Hello-world.ino

This example shows how to send data packet.

#if defined(__PIC32MX__)
#include <WProgram.h>
#else
#include <Arduino.h>
#endif

#if defined(__AVR__) || defined(CORE_TEENSY)
#include <MsTimer2.h>
#elif defined(__SAM3X8E__)
#include <DueTimer.h>
#endif

#include <stddef.h>
#include <stdint.h>
#include <IQRF.h>

// 5000@1ms = 5s
#define USER_TIMER_PERIOD 5000

// TR MODULE PINS
#define TR_RESET_PIN  6   
#define TR_SS_PIN     10  

// LOCAL PROTOTYPES
void setup();
void loop();
void rxHandler();
void txHandler(uint8_t packetId, uint8_t packetResult);
#if defined(__PIC32MX__)
uint32_t msTimerCallback(uint32_t currentTime);
#else
void msTimerCallback();
#endif

// GLOBAL VARIABLES

typedef struct {
    uint8_t rxBuffer[PACKET_SIZE]; 
    uint8_t *txBuffer; 
    uint8_t packetId; 
    volatile uint16_t timer; 
    volatile bool timerAck; 
} appVarsStruct;
appVarsStruct appVars;

IQRF iqrf;
IQRFTR iqrfTr;

// Const data
const char testBuffer[12] = {'H', 'e', 'l', 'l', 'o', ' ', 'W', 'o', 'r', 'l', 'd', '!'};

void setup() {
    // User LED
    pinMode(13, OUTPUT);
    // Up - PC
    Serial.begin(9600);
    // Wait for Serial
    while (!Serial) {
    }
    // Down - IQRF
    iqrf.begin(rxHandler, txHandler);
    // Info - TR
    switch (iqrfTr.getModuleType()) {
        case iqrfTr.types::TR_52D:
            Serial.println("[IQRF] Module type: TR-52D");
            break;
        case iqrfTr.types::TR_72D:
            Serial.println("[IQRF] Module type: TR-72D");
            break;
        default:
            Serial.println("[IQRF] Module type: UNKNOWN");
            break;
    }
#if defined(__AVR__) || defined(CORE_TEENSY)
    MsTimer2::set(1, msTimerCallback);
    MsTimer2::start();
#elif defined(__SAM3X8E__)
    Timer6.attachInterrupt(msTimerCallback).start(1000);
#elif defined(__PIC32MX__)
    attachCoreTimerService(msTimerCallback);
#endif
    // Clear variables
    memset(&appVars, 0, sizeof(appVarsStruct));
    appVars.timer = USER_TIMER_PERIOD;
}

void loop() {
    // TR module SPI comunication driver
    iqrf.driver();
    // Test send data every 5s
    if (appVars.timerAck) {
        // Allocate memory for Tx packet
        appVars.txBuffer = (uint8_t *) malloc(sizeof(testBuffer));
        if (appVars.txBuffer != NULL) {
            // Copy data from test to Tx packet
            memcpy(appVars.txBuffer, (uint8_t *) & testBuffer, sizeof(testBuffer));
            // Send data and unallocate data buffer
            appVars.packetId = iqrf.sendData(appVars.txBuffer, sizeof(testBuffer), 1);
        }
        appVars.timerAck = false;
    }
}

#if defined(__PIC32MX__)

uint32_t msTimerCallback(uint32_t currentTime) {
    // App timer, call handler
    if (appVars.timer) {
        if ((--appVars.timer) == 0) {
            appVars.timerAck = true;
            appVars.timer = USER_TIMER_PERIOD;
        }
    }
    return(currentTime + CORE_TICK_RATE);
}

#else

void msTimerCallback() {
    // App timer, call handler
    if (appVars.timer) {
        if ((--appVars.timer) == 0) {
            appVars.timerAck = true;
            appVars.timer = USER_TIMER_PERIOD;
        }
    }
}

#endif

void rxHandler() {
    // Read and print received data
    iqrf.getData(appVars.rxBuffer, iqrf.getDataLength());
    Serial.print("[IQRF] Receive done: ");
    Serial.write(appVars.rxBuffer, iqrf.getDataLength());
    Serial.println();
}

void txHandler(uint8_t packetId, uint8_t packetResult) {
    Serial.println("[IQRF] Send done");
}